﻿becoming_dragonborn_decision = {
	picture = { reference = "gfx/interface/illustrations/decisions/decision_misc.dds" }
	ai_check_interval = 120
	cooldown = { years = 1 }
	desc = becoming_dragonborn_decision_desc
	decision_group_type = major

	is_shown = {
		is_ai = no
		is_landed = yes
		any_character_artifact = {
			has_artifact_modifier = aok_modifier
		}
		NOR = {
			has_trait = dragonborn
			has_character_flag = race_daedra
		}
	}
	is_valid = {
		age >= 12
		custom_tooltip = {
			text = have_db_amulet
			any_character_artifact = {
				has_artifact_modifier = aok_modifier
			}
		}
		OR = {
			has_trait = p_dv_akatosh
			has_trait = p_dv_shezarr
			has_trait = p_ae_lorkhan
			has_trait = p_at_fox
			has_trait = p_at_bear
		}
		faith = {
			OR = { #is available to faiths that worship the Divines or are otherwise part of the Divines religious sphere
				has_doctrine = doctrine_pantheon_divines
				has_doctrine = doctrine_pantheon_nord
				has_doctrine = doctrine_pantheon_redguard
				has_doctrine = doctrine_pantheon_nedic_aedra
				has_doctrine = special_doctrine_cyrodiilic_cult
				has_doctrine = special_doctrine_bretic_traditions
				has_doctrine = doctrine_sp_dv_talos 
				has_doctrine = special_doctrine_talos_cult 
				has_doctrine = doctrine_pantheon_breton
				has_doctrine = doctrine_sp_breton
				has_doctrine = doctrine_sp_nord
				has_doctrine = doctrine_sp_redguard
				has_doctrine = doctrine_sp_divines
			}
		}
	}
	effect = {
		custom_tooltip = {
			text = becoming_dragonborn_decision_effect_1
			trigger_event = { id = becoming_dragonborn.0002 }
		}
	}
	cost = {
		piety = 1000
	}
}

becoming_dragonborn_camp_decision = {
	picture = { reference = "gfx/interface/illustrations/decisions/decision_misc.dds" }
	ai_check_interval = 120
	cooldown = { days = 5 }
	desc = becoming_dragonborn_camp_decision_desc
	decision_group_type = adventurer

	is_shown = {
		is_ai = no
		is_landless_adventurer = yes
		OR = {
			has_trait = p_dv_akatosh
			has_trait = p_dv_shezarr
			has_trait = p_at_fox
			has_trait = p_at_bear
		}
		faith = {
			OR = { #is available to faiths that worship the Divines or are otherwise part of the Divines religious sphere
				has_doctrine = doctrine_pantheon_divines
				has_doctrine = doctrine_pantheon_nord
				has_doctrine = doctrine_pantheon_redguard
				has_doctrine = doctrine_pantheon_nedic_aedra
				has_doctrine = special_doctrine_cyrodiilic_cult
				has_doctrine = special_doctrine_bretic_traditions
				has_doctrine = doctrine_sp_dv_talos 
				has_doctrine = special_doctrine_talos_cult
				has_doctrine = doctrine_pantheon_breton
			}
		}
		any_character_artifact = {
			has_artifact_modifier = aok_modifier
		}
		NOR = {
			has_trait = dragonborn
			has_character_flag = race_daedra
		}
	}
	is_valid = {
		age >= 16
		custom_tooltip = {
			text = have_db_amulet
			any_character_artifact = {
				has_artifact_modifier = aok_modifier
			}
		}
	}
	effect = {
		custom_tooltip = {
			text = becoming_dragonborn_camp_decision_effect_1
			trigger_event = { id = becoming_dragonborn.0002 }
		}
	}
	cost = {
		gold = 200
		piety = 1000
	}
}